      SUBROUTINE BTPRD(M,N,A,KA,ML,MU,X,Y)
C     ******************************************************************
C     PRODUCT OF A VECTOR AND A BANDED MATRIX
C     ******************************************************************
      REAL A(KA,N),X(M),Y(N)
      DOUBLE PRECISION DSUM
C
C     COMPUTE THE FIRST MU COMPONENTS
C
      JCOL = ML + 1
      IF (MU .EQ. 0) GO TO 20
      DO 11 J = 1,MU
      KMAX = MIN0(M,J+ML)
      JJ = JCOL
      DSUM = 0.0
        DO 10 K = 1,KMAX
        DSUM = DSUM + DBLE(A(K,JJ))*DBLE(X(K))
   10   JJ = JJ - 1
      Y(J) = DSUM
   11 JCOL = JCOL + 1
C
C     COMPUTE THE REMAINING NONZERO COMPONENTS
C
   20 JMIN = MU + 1
      JMAX = MIN0(N,M+MU)
      DO 22 J = JMIN,JMAX
      KMIN = J - MU
      KMAX = MIN0(M,J+ML)
      JJ = JCOL
      DSUM = 0.0
        DO 21 K = KMIN,KMAX
        DSUM = DSUM + DBLE(A(K,JJ))*DBLE(X(K))
   21   JJ = JJ - 1
   22 Y(J) = DSUM
C
C     STORE ZEROS IN THE FINAL N-JMAX COMPONENTS
C
      IF (JMAX .EQ. N) RETURN
      JMIN = JMAX + 1
      DO 30 J = JMIN,N
   30 Y(J) = 0.0
      RETURN
      END
