      SUBROUTINE INTERP (TOUT, Y, N0, Y0)
C-----------------------------------------------------------------------
C SUBROUTINE INTERP COMPUTES INTERPOLATED VALUES OF THE DEPENDENT
C VARIABLE Y AND STORES THEM IN Y0.  THE INTERPOLATION IS TO THE
C POINT T = TOUT AND USES THE NORDSIECK HISTORY ARRAY Y AS FOLLOWS..
C                             NQ
C                  Y0(I)  =  SUM  Y(I,J+1)*S**J ,
C                            J=0
C WHERE S = -(T-TOUT)/H.
C-----------------------------------------------------------------------
C CAUTION   NOT ALL MEMBERS OF EPCOM1 ARE USED IN THIS SUBROUTINE.
C-----------------------------------------------------------------------
      INTEGER N0
      INTEGER JSTART, KFLAG, MF, N
      INTEGER I, J, L
      REAL TOUT, Y, Y0
      REAL EPS, H, HMAX, HMIN, SS, T, UROUND
      REAL S, S1
      REAL ONE
      DIMENSION Y0(N0),Y(N0,13)
C
      COMMON /EPCOM1/ T,H,HMIN,HMAX,EPS,SS,UROUND,N,MF,KFLAG,JSTART
      DATA ONE /1.0E0/
C
      DO 10 I = 1,N
 10     Y0(I) = Y(I,1)
      L = JSTART + 1
      S = (TOUT - T)/H
      S1 = ONE
      DO 30 J = 2,L
        S1 = S1*S
        DO 20 I = 1,N
 20       Y0(I) = Y0(I) + S1*Y(I,J)
 30     CONTINUE
      RETURN
C-----------------------  END OF SUBROUTINE INTERP  --------------------
      END
