      SUBROUTINE MPLNMV (MO, AU, NC, AC, FV)
C     ******************************************************************
C     FORTRAN SUBROUTINE FOR MULTIPLEX POLYNOMIAL EVALUATION
C     ******************************************************************
C     MO = MODE OF OPERATION
C     AU = ARGUMENT U
C     NC = NUMBER OF COEFFICIENTS
C     AC = ARRAY OF COEFFICIENTS
C     FV = FUNCTION V
C
C     MO = -1 FOR INTEGRAL
C     MO =  0 FOR FUNCTION
C     MO = +1 FOR FIRST DERIVATIVE
C     MO = +2 FOR SECOND DERIVATIVE
C
      DIMENSION AC(1)
  001 FV=0.0
      L=NC
      IF(MO.LT.0)GO TO 002
      IF(MO.EQ.0)GO TO 004
      IF(MO.EQ.1)GO TO 006
      IF(MO.GE.2)GO TO 008
  002 QL=NC
      DO 003 K=1,NC
      FV=AC(L)/QL+AU*FV
      L=L-1
      QL=QL-1.0
  003 CONTINUE
      FV=AU*FV
      RETURN
  004 DO 005 K=1,NC
      FV=AC(L)+AU*FV
      L=L-1
  005 CONTINUE
      RETURN
  006 IF(NC.LE.1)RETURN
      QL=NC
      DO 007 K=2,NC
      QL=QL-1.0
      FV=QL*AC(L)+AU*FV
      L=L-1
  007 CONTINUE
      RETURN
  008 IF(NC.LE.2)RETURN
      QL=NC
      DO 009 K=3,NC
      QL=QL-1.0
      FV=QL*(QL-1.0)*AC(L)+AU*FV
      L=L-1
  009 CONTINUE
      RETURN
      END
